DONUT PROJECT 2015 - How To Create Partially Anonymous Data - Como Manter Informações parcialmente Anônimas

DONUT PROJECT 2015 - How To Create Partially Anonymous Data - Como Manter Informações parcialmente Anônimas

Às vezes é importante tornar as informações contidas em relatórios e dashboards parcialmente anônimas, mantendo certa confidencialidade e discrição de olhos sem autorização para consulta.

O código abaixo permite-nos aplicar tal restrição:

Sub AnonymizeText()

'PURPOSE: Anonymize a number or text so only certain amount of original characters are showing (used alot with credit card #s)

'SOURCE: www.TheSpreadsheetGuru.com

Dim ShowChars As Integer

Dim AnonymChar As String

Dim SymbolString As String

Dim StringLength As Long

Dim AnonymEnd As Boolean

Dim cell As Range

Dim rng As Range

'Do you want to anonymize begining or end of text (TRUE for end, FALSE for beginning)

  AnonymEnd = False

'Number of characters you want to show

  ShowChars = 4

'Symbol you want to replace original characters

  AnonymChar = "*"

'Range where data is stored

  Set rng = Range("A2:A25")

  

'Loop through each cell and anonymize text

  For Each cell In rng.Cells

    

    StringLength = Len(cell.Value)

    SymbolString = Application.WorksheetFunction.Rept(AnonymChar, StringLength - ShowChars)

    

    If StringLength > ShowChars Then

      'Anonymize ending characters (ie 730*******)

        If AnonymEnd = True Then cell.Value = Left(cell.Value, ShowChars) & SymbolString

      

      'Anonymize beginning characters (ie *******540)

        If AnonymEnd = False Then cell.Value = SymbolString & Right(cell.Value, ShowChars)

     

    End If

  

  Next cell

End Sub

Olha como funciona:

Não me recordo de pessoalmente ter necessitado do código acima, mas imagino que poderia ser muito útil em áreas como Recursos Humanos, Auditoria, contas a pagar, folha de pagamento, e Tesouraria. Nestes departamentos os analistas geralmente utilizam dados que incluem números de conta, valores, e outras informações pessoais que provavelmente não devam ser mostrados fora do respectivo departamento.

Ei! Envie seus comentários e sugestões de artigos. Compartilhe este artigo com seus chefes, colegas de trabalho e amigos.

andredinizbernardes@gmail.com