Views

...

Important:

Quaisquer soluções e/ou desenvolvimento de aplicações pessoais, ou da empresa, que não constem neste Blog podem ser tratados como consultoria freelance.

E-mails

Deixe seu e-mail para receber atualizações...

eBook Promo

VBA Excel - Compacte suas Planilhas - Use VBA SaveAs in Excel 2007-2013





Caros, o conhecimento pode ajudar-nos  a melhorar o modo como estamos trabalhando em nossas aplicações MS Excel. 

Imagino que você, desenvolvedor experiente, já tenha desenvolvido diversas aplicações de automação que salvam os seus relatórios, Dashboards, e Scorecards em planilhas como resultado final do seu processo de disponibilização das informações.

Certamente em algum momento parou para refletir em quanto uma pequena, mas importante ação, pode influenciar a sua decisão quanto ao padrão que escolherá para gravar o seu relatório final. Sim, há necessidade de reflexão:

- Se formos enviar tais planilhas por e-mail o tamanho delas é crucial para performance de entrega do processo.

- Se estivermos gravando essas mesmas planilhas em um servidor na rede o seu tamanho é importantíssimo para o tempo que isso levará e também para o espaço que ocupará.

- Se estivermos disponibilizando tais resultados num servidor Sharepoint a preocupação é ainda mais válida nos quesitos performance e alcance de disponibilização.

- Coloque como estímulo para si mesmo que ganhará um dólar por cada KByte que poupar.

É certo que muitos dos colegas que leêm os meus Blogs tenha várias aplicações com um perfil similar ao descrito acima. Em alguns casos tais aplicações já funcionam há vários anos e têm salvado centenas de planilhas através destes. Mas... Sim, sempre existe um "mas...".

Gostaria que as suas planilhas ocupassem um espaço infinitamente menor do que vêm ocupando nos últimos meses (ou mesmo anos)?

Imagine-se gerando as referidas planilhas resultantes das suas aplicações, digamos que estas tenham em média um tamanho entre 3 MB e 6 MB. Se você conseguir assimilar as técnicas que descreverei abaixo poderá salvar todas as suas planilhas com pelo menos um oitavo (1/8) desse tamanho.

Como? 

Simples salvando-as como .XLSB.

Antes de mais nada preciso alertá-los de que tais técnicas somente são possíveis a partir da versão do Office 2007. Se ainda não a tem, sinto muito por você, mas ainda precisará continuar a gerar planilhas enormes sem necessidade, até que troque a versão do seu MS Office e então volte aqui.

Nas versões anteriores a 2007 do MS Office não precisávamos especificar o tipo de extensão das nossas planilhas ao gravá-las internamente com o VBA (SaveAs). Não havia problemas quanto a escrevermos o nosso código VBA e não explicitarmos a extensão que desejávamos. 

Por exemplo, no Excel 2007-2013, gravarmos uma planilha ativa com o código antigo abaixo nos daria problemas:

ActiveWorkbook.SaveAs "C:\Bernardes\Dashboard_001_JK.xlsm"

Mas este código abaixo funcionará sem problemas:

ActiveWorkbook.SaveAs "C:\Bernardes\Dashboard_001_JK.xlsm", fileformat:=52 

' 52 = xlOpenXMLWorkbookMacroEnabled = xlsm (para códigos VBA na versão 2007-2013)

Abaixo observamos os principais formatos no Excel 2007-2013:

51 = xlOpenXMLWorkbook (planilha sem macro no 2007-2013, xlsx)

52 = xlOpenXMLWorkbookMacroEnabled (planilha com ou sem macro no 2007-2010, xlsm)

50 = xlExcel12 (Planilha Binária no 2007-2010 com ou sem macro, xlsb)

56 = xlExcel8 (Formato compatível com as versões 97-2003 e Excel 2007-2010, xls)

Mas também é verdade que podemos salvar os arquivos em outros formatos:

FileExtStr = ".csv": FileFormatNum = 6

FileExtStr = ".txt": FileFormatNum = -4158

FileExtStr = ".prn": FileFormatNum = 36

Note: Costumo usar o número que corresponde ao formato que desejo gravar. Ao instanciar as minhas constantes procuro definí-las de modo que minhas planilhas sejam compiladas sem problemas. Isso torna o meu código mais compatível com as versões 97-2003 das minhas planilhas. Por exemplo, o Excel 97-2003 não consegue saber o que a constate xlOpenXMLWorkbookMacroEnabled significa.

Postarei 2 códigos de exemplos que copiam a planilha ativa (ActiveSheet) para uma nova planilha (new Workbook), salvando-a no formato que combina com a extensão do arquivo de origem (Pode usar com o Excel 97-2010). já o segundo exemplo usará GetSaveAsFilename que solicita um Nome e Lugar onde gravar a planilha (Pode usar com o Excel 2000-2010).

1º Exemplo:

Sub Copy_ActiveSheet_1()
'Working in Excel 97-2010
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String

    With Application
        Let .ScreenUpdating = False
        Let .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the sheet to a new workbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            Let FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2010
            'We exit the sub when your answer is NO in the security dialog that you
            'only see when you copy a sheet from a xlsm file with macro's disabled.
            If Sourcewb.Name = .Name Then
                With Application
                    Let .ScreenUpdating = True
                    Let .EnableEvents = True
                End With
                MsgBox "Your answer is NO in the security dialog"
                Exit Sub
            Else
                Select Case Sourcewb.FileFormat
                Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
                Case 52:
                    If .HasVBProject Then
                        Let FileExtStr = ".xlsm": FileFormatNum = 52
                    Else
                        Let FileExtStr = ".xlsx": FileFormatNum = 51
                    End If
                Case 56: FileExtStr = ".xls": FileFormatNum = 56
                Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
                End Select
            End If
        End If
    End With

    '    'Change all cells in the worksheet to values if you want
    '    With Destwb.Sheets(1).UsedRange
    '        .Cells.Copy
    '        .Cells.PasteSpecial xlPasteValues
    '        .Cells(1).Select
    '    End With
    '    Application.CutCopyMode = False

    'Save the new workbook and close it
    Let TempFilePath = Application.DefaultFilePath & "\"
    Let TempFileName = "Part of " & Sourcewb.Name & " " & Format(Now, "yyyy-mm-dd hh-mm-ss")

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        .Close SaveChanges:=False
    End With

    MsgBox "You can find the new file in " & TempFilePath 

    With Application
        Let .ScreenUpdating = True
        Let .EnableEvents = True
    End With
End Sub

2º Exemplo:

Sub Copy_ActiveSheet_2()
'Working in Excel 2000-2010
    Dim fname As Variant
    Dim NewWb As Workbook
    Dim FileFormatValue As Long

    'Check the Excel version
    If Val(Application.Version) < 9 Then Exit Sub
    If Val(Application.Version) < 12 Then

        'Only choice in the "Save as type" dropdown is Excel files(xls)
        'because the Excel version is 2000-2003
        Let fname = Application.GetSaveAsFilename(InitialFileName:="", _
        filefilter:="Excel Files (*.xls), *.xls", _
        Title:="This example copies the ActiveSheet to a new workbook")

        If fname <> False Then
            'Copy the ActiveSheet to new workbook
            ActiveSheet.Copy
            Set NewWb = ActiveWorkbook

            'We use the 2000-2003 format xlWorkbookNormal here to save as xls
            NewWb.SaveAs fname, FileFormat:=-4143, CreateBackup:=False
            NewWb.Close False
            Set NewWb = Nothing

        End If
    Else
        'Give the user the choice to save in 2000-2003 format or in one of the
        'new formats. Use the "Save as type" dropdown to make a choice,Default =
        'Excel Macro Enabled Workbook. You can add or remove formats to/from the list
        
        fname = Application.GetSaveAsFilename(InitialFileName:="", filefilter:= _
        " Excel Macro Free Workbook (*.xlsx), *.xlsx," & _
        " Excel Macro Enabled Workbook (*.xlsm), *.xlsm," & _
        " Excel 2000-2003 Workbook (*.xls), *.xls," & _
        " Excel Binary Workbook (*.xlsb), *.xlsb", _
        FilterIndex:=2, Title:="This example copies the ActiveSheet to a new workbook")

        'Find the correct FileFormat that match the choice in the "Save as type" list
        If fname <> False Then
            Select Case LCase(Right(fname, Len(fname) - InStrRev(fname, ".", , 1)))
            Case "xls": FileFormatValue = 56
            Case "xlsx": FileFormatValue = 51
            Case "xlsm": FileFormatValue = 52
            Case "xlsb": FileFormatValue = 50
            Case Else: FileFormatValue = 0
            End Select

            'Now we can create/Save the file with the xlFileFormat parameter
            'value that match the file extension
            If FileFormatValue = 0 Then
                MsgBox "Sorry, unknown file extension"
            Else
                'Copies the ActiveSheet to new workbook
                ActiveSheet.Copy
                Set NewWb = ActiveWorkbook

                'Save the file in the format you choose in the "Save as type" dropdown
                NewWb.SaveAs fname, FileFormat:= _
                             FileFormatValue, CreateBackup:=False
                NewWb.Close False
                Set NewWb = Nothing

            End If
        End If
    End If
End Sub

Reference: Ron de Bruin

Tags: VBA, Excel, Save, Salvar, xlsx, xlsb, compact, SaveAs,



eBooks VBA na AMAZOM.com.br

LinkWithinBrazilVBAExcelSpecialist

Related Posts Plugin for WordPress, Blogger...

Vitrine